# SPDX-License-Identifier: GPL-3.0-or-later
cmake_minimum_required (VERSION 3.12)
project (NSISPreflightFixture VERSION 1.0.0 LANGUAGES C)

if (NOT WIN32 OR NOT SOURCE_DIR OR NOT FIXTURE_ID)
  message (FATAL_ERROR "Windows, SOURCE_DIR, and a unique FIXTURE_ID are required")
endif ()
file (TO_CMAKE_PATH "${SOURCE_DIR}" SOURCE_DIR)
set (FIXTURE_VERSION 1 CACHE STRING "Payload version")
option (LATE_CONFLICT "Pause after preflight using named Windows events" OFF)

add_executable (fixture_app payload.c)
set_target_properties (fixture_app PROPERTIES OUTPUT_NAME wsjtx)
target_compile_definitions (fixture_app PRIVATE FIXTURE_VERSION=${FIXTURE_VERSION})
add_library (fixture_dll SHARED payload.c)
set_target_properties (fixture_dll PROPERTIES PREFIX "" OUTPUT_NAME payload)
target_compile_definitions (fixture_dll PRIVATE FIXTURE_DLL FIXTURE_VERSION=${FIXTURE_VERSION})
add_executable (fixture_launcher launcher.c)
target_link_libraries (fixture_launcher PRIVATE shell32)
install (TARGETS fixture_app fixture_dll RUNTIME DESTINATION bin)
file (WRITE "${CMAKE_CURRENT_BINARY_DIR}/first.txt" "First payload version ${FIXTURE_VERSION}\n")
file (WRITE "${CMAKE_CURRENT_BINARY_DIR}/last.txt" "Last payload version ${FIXTURE_VERSION}\n")
install (FILES "${CMAKE_CURRENT_BINARY_DIR}/first.txt" DESTINATION data RENAME "00 first.txt")
install (FILES "${CMAKE_CURRENT_BINARY_DIR}/last.txt" DESTINATION data RENAME "zz last.txt")
install (FILES "${CMAKE_CURRENT_BINARY_DIR}/last.txt" DESTINATION "data/Unicode café" RENAME "dollar $ payload.txt")

list (INSERT CMAKE_MODULE_PATH 0 "${SOURCE_DIR}/CMake/Modules")
set (CPACK_GENERATOR NSIS)
set (CPACK_PACKAGE_NAME "WSJTX-preflight-${FIXTURE_ID}")
set (CPACK_PACKAGE_VENDOR "WSJTX installer tests")
set (CPACK_PACKAGE_VERSION "${FIXTURE_VERSION}.0.0")
set (CPACK_PACKAGE_INSTALL_REGISTRY_KEY "${CPACK_PACKAGE_NAME}")
set (CPACK_PACKAGE_INSTALL_DIRECTORY "${CPACK_PACKAGE_NAME}")
set (CPACK_RESOURCE_FILE_LICENSE "${SOURCE_DIR}/COPYING")
set (CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL OFF)
set (CPACK_NSIS_MODIFY_PATH OFF)
set (CPACK_NSIS_MUI_FINISHPAGE_RUN wsjtx.exe)
set (CPACK_NSIS_COMPRESSOR "/SOLID lzma")
set (CPACK_PACKAGE_FILE_NAME "fixture-${FIXTURE_VERSION}")
set (CPACK_PROJECT_CONFIG_FILE "${CMAKE_CURRENT_BINARY_DIR}/options.cmake")
configure_file (options.cmake.in "${CPACK_PROJECT_CONFIG_FILE}" @ONLY)
include (CPack)
